Suppress CR in quiet mode, patch by Derek Fawcus.

[pforth] / fth / tut.fth

anew task-tut.fth\r
\r
: SUM.OF.N.A ( N -- SUM[N] , calculate sum of N integers )\r
           0  \ starting value of SUM\r
           BEGIN\r
               OVER 0>   \ Is N greater than zero?\r
           WHILE\r
               OVER +  \ add N to sum\r
               SWAP 1- SWAP  \ decrement N\r
           REPEAT\r
           SWAP DROP  \ get rid on N\r
       ;\r
\r
: SUM.OF.N.B  ( N -- SUM[N] )\r
    0 SWAP  \ starting value of SUM\r
    1+ 0    \ set indices for DO LOOP\r
    ?DO     \ safer than DO if N=0\r
        I +\r
    LOOP\r
;\r
\r
: SUM.OF.N.C  ( N -- SUM[N] )\r
    0  \ starting value of SUM\r
    BEGIN   ( -- N' SUM )\r
    	OVER +\r
    	SWAP 1- SWAP\r
    	OVER 0<\r
    UNTIL\r
    SWAP DROP\r
;\r
\r
: SUM.OF.N.D  ( N -- SUM[N] )\r
	>R  \ put NUM on return stack\r
    0  \ starting value of SUM\r
    BEGIN   ( -- SUM )\r
    	R@ +  \ add num to sum\r
    	R> 1- DUP >R\r
    	0<\r
    UNTIL\r
    RDROP  \ get rid of NUM\r
;\r
\r
: SUM.OF.N.E  { NUM | SUM -- SUM[N] , use return stack }\r
    BEGIN  \r
    	NUM +-> SUM \ add NUM to SUM\r
    	-1 +-> NUM  \ decrement NUM\r
    	NUM 0<\r
    UNTIL\r
    SUM  \ return SUM\r
;\r
\r
: SUM.OF.N.F  ( NUM -- SUM[N] , Gauss' method )\r
    DUP 1+ * 2/\r
;\r
\r
\r
: TTT\r
	10 0\r
	DO\r
		I SUM.OF.N.A .\r
		I SUM.OF.N.B .\r
		I SUM.OF.N.C .\r
		I SUM.OF.N.D .\r
		I SUM.OF.N.E .\r
		I SUM.OF.N.F .\r
		CR\r
	LOOP\r
;\r
TTT\r
\r