Commit | Line | Data |
---|---|---|
920dae64 AT |
1 | =head1 NAME |
2 | ||
3 | perldata - Perl data types | |
4 | ||
5 | =head1 DESCRIPTION | |
6 | ||
7 | =head2 Variable names | |
8 | X<variable, name> X<variable name> X<data type> X<type> | |
9 | ||
10 | Perl has three built-in data types: scalars, arrays of scalars, and | |
11 | associative arrays of scalars, known as "hashes". A scalar is a | |
12 | single string (of any size, limited only by the available memory), | |
13 | number, or a reference to something (which will be discussed | |
14 | in L<perlref>). Normal arrays are ordered lists of scalars indexed | |
15 | by number, starting with 0. Hashes are unordered collections of scalar | |
16 | values indexed by their associated string key. | |
17 | ||
18 | Values are usually referred to by name, or through a named reference. | |
19 | The first character of the name tells you to what sort of data | |
20 | structure it refers. The rest of the name tells you the particular | |
21 | value to which it refers. Usually this name is a single I<identifier>, | |
22 | that is, a string beginning with a letter or underscore, and | |
23 | containing letters, underscores, and digits. In some cases, it may | |
24 | be a chain of identifiers, separated by C<::> (or by the slightly | |
25 | archaic C<'>); all but the last are interpreted as names of packages, | |
26 | to locate the namespace in which to look up the final identifier | |
27 | (see L<perlmod/Packages> for details). It's possible to substitute | |
28 | for a simple identifier, an expression that produces a reference | |
29 | to the value at runtime. This is described in more detail below | |
30 | and in L<perlref>. | |
31 | X<identifier> | |
32 | ||
33 | Perl also has its own built-in variables whose names don't follow | |
34 | these rules. They have strange names so they don't accidentally | |
35 | collide with one of your normal variables. Strings that match | |
36 | parenthesized parts of a regular expression are saved under names | |
37 | containing only digits after the C<$> (see L<perlop> and L<perlre>). | |
38 | In addition, several special variables that provide windows into | |
39 | the inner working of Perl have names containing punctuation characters | |
40 | and control characters. These are documented in L<perlvar>. | |
41 | X<variable, built-in> | |
42 | ||
43 | Scalar values are always named with '$', even when referring to a | |
44 | scalar that is part of an array or a hash. The '$' symbol works | |
45 | semantically like the English word "the" in that it indicates a | |
46 | single value is expected. | |
47 | X<scalar> | |
48 | ||
49 | $days # the simple scalar value "days" | |
50 | $days[28] # the 29th element of array @days | |
51 | $days{'Feb'} # the 'Feb' value from hash %days | |
52 | $#days # the last index of array @days | |
53 | ||
54 | Entire arrays (and slices of arrays and hashes) are denoted by '@', | |
55 | which works much like the word "these" or "those" does in English, | |
56 | in that it indicates multiple values are expected. | |
57 | X<array> | |
58 | ||
59 | @days # ($days[0], $days[1],... $days[n]) | |
60 | @days[3,4,5] # same as ($days[3],$days[4],$days[5]) | |
61 | @days{'a','c'} # same as ($days{'a'},$days{'c'}) | |
62 | ||
63 | Entire hashes are denoted by '%': | |
64 | X<hash> | |
65 | ||
66 | %days # (key1, val1, key2, val2 ...) | |
67 | ||
68 | In addition, subroutines are named with an initial '&', though this | |
69 | is optional when unambiguous, just as the word "do" is often redundant | |
70 | in English. Symbol table entries can be named with an initial '*', | |
71 | but you don't really care about that yet (if ever :-). | |
72 | ||
73 | Every variable type has its own namespace, as do several | |
74 | non-variable identifiers. This means that you can, without fear | |
75 | of conflict, use the same name for a scalar variable, an array, or | |
76 | a hash--or, for that matter, for a filehandle, a directory handle, a | |
77 | subroutine name, a format name, or a label. This means that $foo | |
78 | and @foo are two different variables. It also means that C<$foo[1]> | |
79 | is a part of @foo, not a part of $foo. This may seem a bit weird, | |
80 | but that's okay, because it is weird. | |
81 | X<namespace> | |
82 | ||
83 | Because variable references always start with '$', '@', or '%', the | |
84 | "reserved" words aren't in fact reserved with respect to variable | |
85 | names. They I<are> reserved with respect to labels and filehandles, | |
86 | however, which don't have an initial special character. You can't | |
87 | have a filehandle named "log", for instance. Hint: you could say | |
88 | C<open(LOG,'logfile')> rather than C<open(log,'logfile')>. Using | |
89 | uppercase filehandles also improves readability and protects you | |
90 | from conflict with future reserved words. Case I<is> significant--"FOO", | |
91 | "Foo", and "foo" are all different names. Names that start with a | |
92 | letter or underscore may also contain digits and underscores. | |
93 | X<identifier, case sensitivity> | |
94 | X<case> | |
95 | ||
96 | It is possible to replace such an alphanumeric name with an expression | |
97 | that returns a reference to the appropriate type. For a description | |
98 | of this, see L<perlref>. | |
99 | ||
100 | Names that start with a digit may contain only more digits. Names | |
101 | that do not start with a letter, underscore, digit or a caret (i.e. | |
102 | a control character) are limited to one character, e.g., C<$%> or | |
103 | C<$$>. (Most of these one character names have a predefined | |
104 | significance to Perl. For instance, C<$$> is the current process | |
105 | id.) | |
106 | ||
107 | =head2 Context | |
108 | X<context> X<scalar context> X<list context> | |
109 | ||
110 | The interpretation of operations and values in Perl sometimes depends | |
111 | on the requirements of the context around the operation or value. | |
112 | There are two major contexts: list and scalar. Certain operations | |
113 | return list values in contexts wanting a list, and scalar values | |
114 | otherwise. If this is true of an operation it will be mentioned in | |
115 | the documentation for that operation. In other words, Perl overloads | |
116 | certain operations based on whether the expected return value is | |
117 | singular or plural. Some words in English work this way, like "fish" | |
118 | and "sheep". | |
119 | ||
120 | In a reciprocal fashion, an operation provides either a scalar or a | |
121 | list context to each of its arguments. For example, if you say | |
122 | ||
123 | int( <STDIN> ) | |
124 | ||
125 | the integer operation provides scalar context for the <> | |
126 | operator, which responds by reading one line from STDIN and passing it | |
127 | back to the integer operation, which will then find the integer value | |
128 | of that line and return that. If, on the other hand, you say | |
129 | ||
130 | sort( <STDIN> ) | |
131 | ||
132 | then the sort operation provides list context for <>, which | |
133 | will proceed to read every line available up to the end of file, and | |
134 | pass that list of lines back to the sort routine, which will then | |
135 | sort those lines and return them as a list to whatever the context | |
136 | of the sort was. | |
137 | ||
138 | Assignment is a little bit special in that it uses its left argument | |
139 | to determine the context for the right argument. Assignment to a | |
140 | scalar evaluates the right-hand side in scalar context, while | |
141 | assignment to an array or hash evaluates the righthand side in list | |
142 | context. Assignment to a list (or slice, which is just a list | |
143 | anyway) also evaluates the righthand side in list context. | |
144 | ||
145 | When you use the C<use warnings> pragma or Perl's B<-w> command-line | |
146 | option, you may see warnings | |
147 | about useless uses of constants or functions in "void context". | |
148 | Void context just means the value has been discarded, such as a | |
149 | statement containing only C<"fred";> or C<getpwuid(0);>. It still | |
150 | counts as scalar context for functions that care whether or not | |
151 | they're being called in list context. | |
152 | ||
153 | User-defined subroutines may choose to care whether they are being | |
154 | called in a void, scalar, or list context. Most subroutines do not | |
155 | need to bother, though. That's because both scalars and lists are | |
156 | automatically interpolated into lists. See L<perlfunc/wantarray> | |
157 | for how you would dynamically discern your function's calling | |
158 | context. | |
159 | ||
160 | =head2 Scalar values | |
161 | X<scalar> X<number> X<string> X<reference> | |
162 | ||
163 | All data in Perl is a scalar, an array of scalars, or a hash of | |
164 | scalars. A scalar may contain one single value in any of three | |
165 | different flavors: a number, a string, or a reference. In general, | |
166 | conversion from one form to another is transparent. Although a | |
167 | scalar may not directly hold multiple values, it may contain a | |
168 | reference to an array or hash which in turn contains multiple values. | |
169 | ||
170 | Scalars aren't necessarily one thing or another. There's no place | |
171 | to declare a scalar variable to be of type "string", type "number", | |
172 | type "reference", or anything else. Because of the automatic | |
173 | conversion of scalars, operations that return scalars don't need | |
174 | to care (and in fact, cannot care) whether their caller is looking | |
175 | for a string, a number, or a reference. Perl is a contextually | |
176 | polymorphic language whose scalars can be strings, numbers, or | |
177 | references (which includes objects). Although strings and numbers | |
178 | are considered pretty much the same thing for nearly all purposes, | |
179 | references are strongly-typed, uncastable pointers with builtin | |
180 | reference-counting and destructor invocation. | |
181 | ||
182 | A scalar value is interpreted as TRUE in the Boolean sense if it is not | |
183 | the null string or the number 0 (or its string equivalent, "0"). The | |
184 | Boolean context is just a special kind of scalar context where no | |
185 | conversion to a string or a number is ever performed. | |
186 | X<boolean> X<bool> X<true> X<false> X<truth> | |
187 | ||
188 | There are actually two varieties of null strings (sometimes referred | |
189 | to as "empty" strings), a defined one and an undefined one. The | |
190 | defined version is just a string of length zero, such as C<"">. | |
191 | The undefined version is the value that indicates that there is | |
192 | no real value for something, such as when there was an error, or | |
193 | at end of file, or when you refer to an uninitialized variable or | |
194 | element of an array or hash. Although in early versions of Perl, | |
195 | an undefined scalar could become defined when first used in a | |
196 | place expecting a defined value, this no longer happens except for | |
197 | rare cases of autovivification as explained in L<perlref>. You can | |
198 | use the defined() operator to determine whether a scalar value is | |
199 | defined (this has no meaning on arrays or hashes), and the undef() | |
200 | operator to produce an undefined value. | |
201 | X<defined> X<undefined> X<undef> X<null> X<string, null> | |
202 | ||
203 | To find out whether a given string is a valid non-zero number, it's | |
204 | sometimes enough to test it against both numeric 0 and also lexical | |
205 | "0" (although this will cause noises if warnings are on). That's | |
206 | because strings that aren't numbers count as 0, just as they do in B<awk>: | |
207 | ||
208 | if ($str == 0 && $str ne "0") { | |
209 | warn "That doesn't look like a number"; | |
210 | } | |
211 | ||
212 | That method may be best because otherwise you won't treat IEEE | |
213 | notations like C<NaN> or C<Infinity> properly. At other times, you | |
214 | might prefer to determine whether string data can be used numerically | |
215 | by calling the POSIX::strtod() function or by inspecting your string | |
216 | with a regular expression (as documented in L<perlre>). | |
217 | ||
218 | warn "has nondigits" if /\D/; | |
219 | warn "not a natural number" unless /^\d+$/; # rejects -3 | |
220 | warn "not an integer" unless /^-?\d+$/; # rejects +3 | |
221 | warn "not an integer" unless /^[+-]?\d+$/; | |
222 | warn "not a decimal number" unless /^-?\d+\.?\d*$/; # rejects .2 | |
223 | warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/; | |
224 | warn "not a C float" | |
225 | unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/; | |
226 | ||
227 | The length of an array is a scalar value. You may find the length | |
228 | of array @days by evaluating C<$#days>, as in B<csh>. However, this | |
229 | isn't the length of the array; it's the subscript of the last element, | |
230 | which is a different value since there is ordinarily a 0th element. | |
231 | Assigning to C<$#days> actually changes the length of the array. | |
232 | Shortening an array this way destroys intervening values. Lengthening | |
233 | an array that was previously shortened does not recover values | |
234 | that were in those elements. (It used to do so in Perl 4, but we | |
235 | had to break this to make sure destructors were called when expected.) | |
236 | X<$#> X<array, length> | |
237 | ||
238 | You can also gain some minuscule measure of efficiency by pre-extending | |
239 | an array that is going to get big. You can also extend an array | |
240 | by assigning to an element that is off the end of the array. You | |
241 | can truncate an array down to nothing by assigning the null list | |
242 | () to it. The following are equivalent: | |
243 | ||
244 | @whatever = (); | |
245 | $#whatever = -1; | |
246 | ||
247 | If you evaluate an array in scalar context, it returns the length | |
248 | of the array. (Note that this is not true of lists, which return | |
249 | the last value, like the C comma operator, nor of built-in functions, | |
250 | which return whatever they feel like returning.) The following is | |
251 | always true: | |
252 | X<array, length> | |
253 | ||
254 | scalar(@whatever) == $#whatever - $[ + 1; | |
255 | ||
256 | Version 5 of Perl changed the semantics of C<$[>: files that don't set | |
257 | the value of C<$[> no longer need to worry about whether another | |
258 | file changed its value. (In other words, use of C<$[> is deprecated.) | |
259 | So in general you can assume that | |
260 | X<$[> | |
261 | ||
262 | scalar(@whatever) == $#whatever + 1; | |
263 | ||
264 | Some programmers choose to use an explicit conversion so as to | |
265 | leave nothing to doubt: | |
266 | ||
267 | $element_count = scalar(@whatever); | |
268 | ||
269 | If you evaluate a hash in scalar context, it returns false if the | |
270 | hash is empty. If there are any key/value pairs, it returns true; | |
271 | more precisely, the value returned is a string consisting of the | |
272 | number of used buckets and the number of allocated buckets, separated | |
273 | by a slash. This is pretty much useful only to find out whether | |
274 | Perl's internal hashing algorithm is performing poorly on your data | |
275 | set. For example, you stick 10,000 things in a hash, but evaluating | |
276 | %HASH in scalar context reveals C<"1/16">, which means only one out | |
277 | of sixteen buckets has been touched, and presumably contains all | |
278 | 10,000 of your items. This isn't supposed to happen. | |
279 | X<hash, scalar context> X<hash, bucket> X<bucket> | |
280 | ||
281 | You can preallocate space for a hash by assigning to the keys() function. | |
282 | This rounds up the allocated buckets to the next power of two: | |
283 | ||
284 | keys(%users) = 1000; # allocate 1024 buckets | |
285 | ||
286 | =head2 Scalar value constructors | |
287 | X<scalar, literal> X<scalar, constant> | |
288 | ||
289 | Numeric literals are specified in any of the following floating point or | |
290 | integer formats: | |
291 | ||
292 | 12345 | |
293 | 12345.67 | |
294 | .23E-10 # a very small number | |
295 | 3.14_15_92 # a very important number | |
296 | 4_294_967_296 # underscore for legibility | |
297 | 0xff # hex | |
298 | 0xdead_beef # more hex | |
299 | 0377 # octal (only numbers, begins with 0) | |
300 | 0b011011 # binary | |
301 | ||
302 | You are allowed to use underscores (underbars) in numeric literals | |
303 | between digits for legibility. You could, for example, group binary | |
304 | digits by threes (as for a Unix-style mode argument such as 0b110_100_100) | |
305 | or by fours (to represent nibbles, as in 0b1010_0110) or in other groups. | |
306 | X<number, literal> | |
307 | ||
308 | String literals are usually delimited by either single or double | |
309 | quotes. They work much like quotes in the standard Unix shells: | |
310 | double-quoted string literals are subject to backslash and variable | |
311 | substitution; single-quoted strings are not (except for C<\'> and | |
312 | C<\\>). The usual C-style backslash rules apply for making | |
313 | characters such as newline, tab, etc., as well as some more exotic | |
314 | forms. See L<perlop/"Quote and Quote-like Operators"> for a list. | |
315 | X<string, literal> | |
316 | ||
317 | Hexadecimal, octal, or binary, representations in string literals | |
318 | (e.g. '0xff') are not automatically converted to their integer | |
319 | representation. The hex() and oct() functions make these conversions | |
320 | for you. See L<perlfunc/hex> and L<perlfunc/oct> for more details. | |
321 | ||
322 | You can also embed newlines directly in your strings, i.e., they can end | |
323 | on a different line than they begin. This is nice, but if you forget | |
324 | your trailing quote, the error will not be reported until Perl finds | |
325 | another line containing the quote character, which may be much further | |
326 | on in the script. Variable substitution inside strings is limited to | |
327 | scalar variables, arrays, and array or hash slices. (In other words, | |
328 | names beginning with $ or @, followed by an optional bracketed | |
329 | expression as a subscript.) The following code segment prints out "The | |
330 | price is $Z<>100." | |
331 | X<interpolation> | |
332 | ||
333 | $Price = '$100'; # not interpolated | |
334 | print "The price is $Price.\n"; # interpolated | |
335 | ||
336 | There is no double interpolation in Perl, so the C<$100> is left as is. | |
337 | ||
338 | As in some shells, you can enclose the variable name in braces to | |
339 | disambiguate it from following alphanumerics (and underscores). | |
340 | You must also do | |
341 | this when interpolating a variable into a string to separate the | |
342 | variable name from a following double-colon or an apostrophe, since | |
343 | these would be otherwise treated as a package separator: | |
344 | X<interpolation> | |
345 | ||
346 | $who = "Larry"; | |
347 | print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n"; | |
348 | print "We use ${who}speak when ${who}'s here.\n"; | |
349 | ||
350 | Without the braces, Perl would have looked for a $whospeak, a | |
351 | C<$who::0>, and a C<$who's> variable. The last two would be the | |
352 | $0 and the $s variables in the (presumably) non-existent package | |
353 | C<who>. | |
354 | ||
355 | In fact, an identifier within such curlies is forced to be a string, | |
356 | as is any simple identifier within a hash subscript. Neither need | |
357 | quoting. Our earlier example, C<$days{'Feb'}> can be written as | |
358 | C<$days{Feb}> and the quotes will be assumed automatically. But | |
359 | anything more complicated in the subscript will be interpreted as an | |
360 | expression. This means for example that C<$version{2.0}++> is | |
361 | equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>. | |
362 | ||
363 | =head3 Version Strings | |
364 | X<version string> X<vstring> X<v-string> | |
365 | ||
366 | B<Note:> Version Strings (v-strings) have been deprecated. They will | |
367 | not be available after Perl 5.8. The marginal benefits of v-strings | |
368 | were greatly outweighed by the potential for Surprise and Confusion. | |
369 | ||
370 | A literal of the form C<v1.20.300.4000> is parsed as a string composed | |
371 | of characters with the specified ordinals. This form, known as | |
372 | v-strings, provides an alternative, more readable way to construct | |
373 | strings, rather than use the somewhat less readable interpolation form | |
374 | C<"\x{1}\x{14}\x{12c}\x{fa0}">. This is useful for representing | |
375 | Unicode strings, and for comparing version "numbers" using the string | |
376 | comparison operators, C<cmp>, C<gt>, C<lt> etc. If there are two or | |
377 | more dots in the literal, the leading C<v> may be omitted. | |
378 | ||
379 | print v9786; # prints UTF-8 encoded SMILEY, "\x{263a}" | |
380 | print v102.111.111; # prints "foo" | |
381 | print 102.111.111; # same | |
382 | ||
383 | Such literals are accepted by both C<require> and C<use> for | |
384 | doing a version check. The C<$^V> special variable also contains the | |
385 | running Perl interpreter's version in this form. See L<perlvar/$^V>. | |
386 | Note that using the v-strings for IPv4 addresses is not portable unless | |
387 | you also use the inet_aton()/inet_ntoa() routines of the Socket package. | |
388 | ||
389 | Note that since Perl 5.8.1 the single-number v-strings (like C<v65>) | |
390 | are not v-strings before the C<< => >> operator (which is usually used | |
391 | to separate a hash key from a hash value), instead they are interpreted | |
392 | as literal strings ('v65'). They were v-strings from Perl 5.6.0 to | |
393 | Perl 5.8.0, but that caused more confusion and breakage than good. | |
394 | Multi-number v-strings like C<v65.66> and C<65.66.67> continue to | |
395 | be v-strings always. | |
396 | ||
397 | =head3 Special Literals | |
398 | X<special literal> X<__END__> X<__DATA__> X<END> X<DATA> | |
399 | X<end> X<data> X<^D> X<^Z> | |
400 | ||
401 | The special literals __FILE__, __LINE__, and __PACKAGE__ | |
402 | represent the current filename, line number, and package name at that | |
403 | point in your program. They may be used only as separate tokens; they | |
404 | will not be interpolated into strings. If there is no current package | |
405 | (due to an empty C<package;> directive), __PACKAGE__ is the undefined | |
406 | value. | |
407 | X<__FILE__> X<__LINE__> X<__PACKAGE__> X<line> X<file> X<package> | |
408 | ||
409 | The two control characters ^D and ^Z, and the tokens __END__ and __DATA__ | |
410 | may be used to indicate the logical end of the script before the actual | |
411 | end of file. Any following text is ignored. | |
412 | ||
413 | Text after __DATA__ but may be read via the filehandle C<PACKNAME::DATA>, | |
414 | where C<PACKNAME> is the package that was current when the __DATA__ | |
415 | token was encountered. The filehandle is left open pointing to the | |
416 | contents after __DATA__. It is the program's responsibility to | |
417 | C<close DATA> when it is done reading from it. For compatibility with | |
418 | older scripts written before __DATA__ was introduced, __END__ behaves | |
419 | like __DATA__ in the toplevel script (but not in files loaded with | |
420 | C<require> or C<do>) and leaves the remaining contents of the | |
421 | file accessible via C<main::DATA>. | |
422 | ||
423 | See L<SelfLoader> for more description of __DATA__, and | |
424 | an example of its use. Note that you cannot read from the DATA | |
425 | filehandle in a BEGIN block: the BEGIN block is executed as soon | |
426 | as it is seen (during compilation), at which point the corresponding | |
427 | __DATA__ (or __END__) token has not yet been seen. | |
428 | ||
429 | =head3 Barewords | |
430 | X<bareword> | |
431 | ||
432 | A word that has no other interpretation in the grammar will | |
433 | be treated as if it were a quoted string. These are known as | |
434 | "barewords". As with filehandles and labels, a bareword that consists | |
435 | entirely of lowercase letters risks conflict with future reserved | |
436 | words, and if you use the C<use warnings> pragma or the B<-w> switch, | |
437 | Perl will warn you about any | |
438 | such words. Some people may wish to outlaw barewords entirely. If you | |
439 | say | |
440 | ||
441 | use strict 'subs'; | |
442 | ||
443 | then any bareword that would NOT be interpreted as a subroutine call | |
444 | produces a compile-time error instead. The restriction lasts to the | |
445 | end of the enclosing block. An inner block may countermand this | |
446 | by saying C<no strict 'subs'>. | |
447 | ||
448 | =head3 Array Joining Delimiter | |
449 | X<array, interpolation> X<interpolation, array> X<$"> | |
450 | ||
451 | Arrays and slices are interpolated into double-quoted strings | |
452 | by joining the elements with the delimiter specified in the C<$"> | |
453 | variable (C<$LIST_SEPARATOR> if "use English;" is specified), | |
454 | space by default. The following are equivalent: | |
455 | ||
456 | $temp = join($", @ARGV); | |
457 | system "echo $temp"; | |
458 | ||
459 | system "echo @ARGV"; | |
460 | ||
461 | Within search patterns (which also undergo double-quotish substitution) | |
462 | there is an unfortunate ambiguity: Is C</$foo[bar]/> to be interpreted as | |
463 | C</${foo}[bar]/> (where C<[bar]> is a character class for the regular | |
464 | expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array | |
465 | @foo)? If @foo doesn't otherwise exist, then it's obviously a | |
466 | character class. If @foo exists, Perl takes a good guess about C<[bar]>, | |
467 | and is almost always right. If it does guess wrong, or if you're just | |
468 | plain paranoid, you can force the correct interpretation with curly | |
469 | braces as above. | |
470 | ||
471 | If you're looking for the information on how to use here-documents, | |
472 | which used to be here, that's been moved to | |
473 | L<perlop/Quote and Quote-like Operators>. | |
474 | ||
475 | =head2 List value constructors | |
476 | X<list> | |
477 | ||
478 | List values are denoted by separating individual values by commas | |
479 | (and enclosing the list in parentheses where precedence requires it): | |
480 | ||
481 | (LIST) | |
482 | ||
483 | In a context not requiring a list value, the value of what appears | |
484 | to be a list literal is simply the value of the final element, as | |
485 | with the C comma operator. For example, | |
486 | ||
487 | @foo = ('cc', '-E', $bar); | |
488 | ||
489 | assigns the entire list value to array @foo, but | |
490 | ||
491 | $foo = ('cc', '-E', $bar); | |
492 | ||
493 | assigns the value of variable $bar to the scalar variable $foo. | |
494 | Note that the value of an actual array in scalar context is the | |
495 | length of the array; the following assigns the value 3 to $foo: | |
496 | ||
497 | @foo = ('cc', '-E', $bar); | |
498 | $foo = @foo; # $foo gets 3 | |
499 | ||
500 | You may have an optional comma before the closing parenthesis of a | |
501 | list literal, so that you can say: | |
502 | ||
503 | @foo = ( | |
504 | 1, | |
505 | 2, | |
506 | 3, | |
507 | ); | |
508 | ||
509 | To use a here-document to assign an array, one line per element, | |
510 | you might use an approach like this: | |
511 | ||
512 | @sauces = <<End_Lines =~ m/(\S.*\S)/g; | |
513 | normal tomato | |
514 | spicy tomato | |
515 | green chile | |
516 | pesto | |
517 | white wine | |
518 | End_Lines | |
519 | ||
520 | LISTs do automatic interpolation of sublists. That is, when a LIST is | |
521 | evaluated, each element of the list is evaluated in list context, and | |
522 | the resulting list value is interpolated into LIST just as if each | |
523 | individual element were a member of LIST. Thus arrays and hashes lose their | |
524 | identity in a LIST--the list | |
525 | ||
526 | (@foo,@bar,&SomeSub,%glarch) | |
527 | ||
528 | contains all the elements of @foo followed by all the elements of @bar, | |
529 | followed by all the elements returned by the subroutine named SomeSub | |
530 | called in list context, followed by the key/value pairs of %glarch. | |
531 | To make a list reference that does I<NOT> interpolate, see L<perlref>. | |
532 | ||
533 | The null list is represented by (). Interpolating it in a list | |
534 | has no effect. Thus ((),(),()) is equivalent to (). Similarly, | |
535 | interpolating an array with no elements is the same as if no | |
536 | array had been interpolated at that point. | |
537 | ||
538 | This interpolation combines with the facts that the opening | |
539 | and closing parentheses are optional (except when necessary for | |
540 | precedence) and lists may end with an optional comma to mean that | |
541 | multiple commas within lists are legal syntax. The list C<1,,3> is a | |
542 | concatenation of two lists, C<1,> and C<3>, the first of which ends | |
543 | with that optional comma. C<1,,3> is C<(1,),(3)> is C<1,3> (And | |
544 | similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.) Not that | |
545 | we'd advise you to use this obfuscation. | |
546 | ||
547 | A list value may also be subscripted like a normal array. You must | |
548 | put the list in parentheses to avoid ambiguity. For example: | |
549 | ||
550 | # Stat returns list value. | |
551 | $time = (stat($file))[8]; | |
552 | ||
553 | # SYNTAX ERROR HERE. | |
554 | $time = stat($file)[8]; # OOPS, FORGOT PARENTHESES | |
555 | ||
556 | # Find a hex digit. | |
557 | $hexdigit = ('a','b','c','d','e','f')[$digit-10]; | |
558 | ||
559 | # A "reverse comma operator". | |
560 | return (pop(@foo),pop(@foo))[0]; | |
561 | ||
562 | Lists may be assigned to only when each element of the list | |
563 | is itself legal to assign to: | |
564 | ||
565 | ($a, $b, $c) = (1, 2, 3); | |
566 | ||
567 | ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00); | |
568 | ||
569 | An exception to this is that you may assign to C<undef> in a list. | |
570 | This is useful for throwing away some of the return values of a | |
571 | function: | |
572 | ||
573 | ($dev, $ino, undef, undef, $uid, $gid) = stat($file); | |
574 | ||
575 | List assignment in scalar context returns the number of elements | |
576 | produced by the expression on the right side of the assignment: | |
577 | ||
578 | $x = (($foo,$bar) = (3,2,1)); # set $x to 3, not 2 | |
579 | $x = (($foo,$bar) = f()); # set $x to f()'s return count | |
580 | ||
581 | This is handy when you want to do a list assignment in a Boolean | |
582 | context, because most list functions return a null list when finished, | |
583 | which when assigned produces a 0, which is interpreted as FALSE. | |
584 | ||
585 | It's also the source of a useful idiom for executing a function or | |
586 | performing an operation in list context and then counting the number of | |
587 | return values, by assigning to an empty list and then using that | |
588 | assignment in scalar context. For example, this code: | |
589 | ||
590 | $count = () = $string =~ /\d+/g; | |
591 | ||
592 | will place into $count the number of digit groups found in $string. | |
593 | This happens because the pattern match is in list context (since it | |
594 | is being assigned to the empty list), and will therefore return a list | |
595 | of all matching parts of the string. The list assignment in scalar | |
596 | context will translate that into the number of elements (here, the | |
597 | number of times the pattern matched) and assign that to $count. Note | |
598 | that simply using | |
599 | ||
600 | $count = $string =~ /\d+/g; | |
601 | ||
602 | would not have worked, since a pattern match in scalar context will | |
603 | only return true or false, rather than a count of matches. | |
604 | ||
605 | The final element of a list assignment may be an array or a hash: | |
606 | ||
607 | ($a, $b, @rest) = split; | |
608 | my($a, $b, %rest) = @_; | |
609 | ||
610 | You can actually put an array or hash anywhere in the list, but the first one | |
611 | in the list will soak up all the values, and anything after it will become | |
612 | undefined. This may be useful in a my() or local(). | |
613 | ||
614 | A hash can be initialized using a literal list holding pairs of | |
615 | items to be interpreted as a key and a value: | |
616 | ||
617 | # same as map assignment above | |
618 | %map = ('red',0x00f,'blue',0x0f0,'green',0xf00); | |
619 | ||
620 | While literal lists and named arrays are often interchangeable, that's | |
621 | not the case for hashes. Just because you can subscript a list value like | |
622 | a normal array does not mean that you can subscript a list value as a | |
623 | hash. Likewise, hashes included as parts of other lists (including | |
624 | parameters lists and return lists from functions) always flatten out into | |
625 | key/value pairs. That's why it's good to use references sometimes. | |
626 | ||
627 | It is often more readable to use the C<< => >> operator between key/value | |
628 | pairs. The C<< => >> operator is mostly just a more visually distinctive | |
629 | synonym for a comma, but it also arranges for its left-hand operand to be | |
630 | interpreted as a string -- if it's a bareword that would be a legal simple | |
631 | identifier (C<< => >> doesn't quote compound identifiers, that contain | |
632 | double colons). This makes it nice for initializing hashes: | |
633 | ||
634 | %map = ( | |
635 | red => 0x00f, | |
636 | blue => 0x0f0, | |
637 | green => 0xf00, | |
638 | ); | |
639 | ||
640 | or for initializing hash references to be used as records: | |
641 | ||
642 | $rec = { | |
643 | witch => 'Mable the Merciless', | |
644 | cat => 'Fluffy the Ferocious', | |
645 | date => '10/31/1776', | |
646 | }; | |
647 | ||
648 | or for using call-by-named-parameter to complicated functions: | |
649 | ||
650 | $field = $query->radio_group( | |
651 | name => 'group_name', | |
652 | values => ['eenie','meenie','minie'], | |
653 | default => 'meenie', | |
654 | linebreak => 'true', | |
655 | labels => \%labels | |
656 | ); | |
657 | ||
658 | Note that just because a hash is initialized in that order doesn't | |
659 | mean that it comes out in that order. See L<perlfunc/sort> for examples | |
660 | of how to arrange for an output ordering. | |
661 | ||
662 | =head2 Subscripts | |
663 | ||
664 | An array is subscripted by specifying a dollar sign (C<$>), then the | |
665 | name of the array (without the leading C<@>), then the subscript inside | |
666 | square brackets. For example: | |
667 | ||
668 | @myarray = (5, 50, 500, 5000); | |
669 | print "Element Number 2 is", $myarray[2], "\n"; | |
670 | ||
671 | The array indices start with 0. A negative subscript retrieves its | |
672 | value from the end. In our example, C<$myarray[-1]> would have been | |
673 | 5000, and C<$myarray[-2]> would have been 500. | |
674 | ||
675 | Hash subscripts are similar, only instead of square brackets curly brackets | |
676 | are used. For example: | |
677 | ||
678 | %scientists = | |
679 | ( | |
680 | "Newton" => "Isaac", | |
681 | "Einstein" => "Albert", | |
682 | "Darwin" => "Charles", | |
683 | "Feynman" => "Richard", | |
684 | ); | |
685 | ||
686 | print "Darwin's First Name is ", $scientists{"Darwin"}, "\n"; | |
687 | ||
688 | =head2 Slices | |
689 | X<slice> X<array, slice> X<hash, slice> | |
690 | ||
691 | A common way to access an array or a hash is one scalar element at a | |
692 | time. You can also subscript a list to get a single element from it. | |
693 | ||
694 | $whoami = $ENV{"USER"}; # one element from the hash | |
695 | $parent = $ISA[0]; # one element from the array | |
696 | $dir = (getpwnam("daemon"))[7]; # likewise, but with list | |
697 | ||
698 | A slice accesses several elements of a list, an array, or a hash | |
699 | simultaneously using a list of subscripts. It's more convenient | |
700 | than writing out the individual elements as a list of separate | |
701 | scalar values. | |
702 | ||
703 | ($him, $her) = @folks[0,-1]; # array slice | |
704 | @them = @folks[0 .. 3]; # array slice | |
705 | ($who, $home) = @ENV{"USER", "HOME"}; # hash slice | |
706 | ($uid, $dir) = (getpwnam("daemon"))[2,7]; # list slice | |
707 | ||
708 | Since you can assign to a list of variables, you can also assign to | |
709 | an array or hash slice. | |
710 | ||
711 | @days[3..5] = qw/Wed Thu Fri/; | |
712 | @colors{'red','blue','green'} | |
713 | = (0xff0000, 0x0000ff, 0x00ff00); | |
714 | @folks[0, -1] = @folks[-1, 0]; | |
715 | ||
716 | The previous assignments are exactly equivalent to | |
717 | ||
718 | ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/; | |
719 | ($colors{'red'}, $colors{'blue'}, $colors{'green'}) | |
720 | = (0xff0000, 0x0000ff, 0x00ff00); | |
721 | ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]); | |
722 | ||
723 | Since changing a slice changes the original array or hash that it's | |
724 | slicing, a C<foreach> construct will alter some--or even all--of the | |
725 | values of the array or hash. | |
726 | ||
727 | foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } | |
728 | ||
729 | foreach (@hash{qw[key1 key2]}) { | |
730 | s/^\s+//; # trim leading whitespace | |
731 | s/\s+$//; # trim trailing whitespace | |
732 | s/(\w+)/\u\L$1/g; # "titlecase" words | |
733 | } | |
734 | ||
735 | A slice of an empty list is still an empty list. Thus: | |
736 | ||
737 | @a = ()[1,0]; # @a has no elements | |
738 | @b = (@a)[0,1]; # @b has no elements | |
739 | @c = (0,1)[2,3]; # @c has no elements | |
740 | ||
741 | But: | |
742 | ||
743 | @a = (1)[1,0]; # @a has two elements | |
744 | @b = (1,undef)[1,0,2]; # @b has three elements | |
745 | ||
746 | This makes it easy to write loops that terminate when a null list | |
747 | is returned: | |
748 | ||
749 | while ( ($home, $user) = (getpwent)[7,0]) { | |
750 | printf "%-8s %s\n", $user, $home; | |
751 | } | |
752 | ||
753 | As noted earlier in this document, the scalar sense of list assignment | |
754 | is the number of elements on the right-hand side of the assignment. | |
755 | The null list contains no elements, so when the password file is | |
756 | exhausted, the result is 0, not 2. | |
757 | ||
758 | If you're confused about why you use an '@' there on a hash slice | |
759 | instead of a '%', think of it like this. The type of bracket (square | |
760 | or curly) governs whether it's an array or a hash being looked at. | |
761 | On the other hand, the leading symbol ('$' or '@') on the array or | |
762 | hash indicates whether you are getting back a singular value (a | |
763 | scalar) or a plural one (a list). | |
764 | ||
765 | =head2 Typeglobs and Filehandles | |
766 | X<typeglob> X<filehandle> X<*> | |
767 | ||
768 | Perl uses an internal type called a I<typeglob> to hold an entire | |
769 | symbol table entry. The type prefix of a typeglob is a C<*>, because | |
770 | it represents all types. This used to be the preferred way to | |
771 | pass arrays and hashes by reference into a function, but now that | |
772 | we have real references, this is seldom needed. | |
773 | ||
774 | The main use of typeglobs in modern Perl is create symbol table aliases. | |
775 | This assignment: | |
776 | ||
777 | *this = *that; | |
778 | ||
779 | makes $this an alias for $that, @this an alias for @that, %this an alias | |
780 | for %that, &this an alias for &that, etc. Much safer is to use a reference. | |
781 | This: | |
782 | ||
783 | local *Here::blue = \$There::green; | |
784 | ||
785 | temporarily makes $Here::blue an alias for $There::green, but doesn't | |
786 | make @Here::blue an alias for @There::green, or %Here::blue an alias for | |
787 | %There::green, etc. See L<perlmod/"Symbol Tables"> for more examples | |
788 | of this. Strange though this may seem, this is the basis for the whole | |
789 | module import/export system. | |
790 | ||
791 | Another use for typeglobs is to pass filehandles into a function or | |
792 | to create new filehandles. If you need to use a typeglob to save away | |
793 | a filehandle, do it this way: | |
794 | ||
795 | $fh = *STDOUT; | |
796 | ||
797 | or perhaps as a real reference, like this: | |
798 | ||
799 | $fh = \*STDOUT; | |
800 | ||
801 | See L<perlsub> for examples of using these as indirect filehandles | |
802 | in functions. | |
803 | ||
804 | Typeglobs are also a way to create a local filehandle using the local() | |
805 | operator. These last until their block is exited, but may be passed back. | |
806 | For example: | |
807 | ||
808 | sub newopen { | |
809 | my $path = shift; | |
810 | local *FH; # not my! | |
811 | open (FH, $path) or return undef; | |
812 | return *FH; | |
813 | } | |
814 | $fh = newopen('/etc/passwd'); | |
815 | ||
816 | Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much | |
817 | for filehandle manipulations, although they're still needed to pass brand | |
818 | new file and directory handles into or out of functions. That's because | |
819 | C<*HANDLE{IO}> only works if HANDLE has already been used as a handle. | |
820 | In other words, C<*FH> must be used to create new symbol table entries; | |
821 | C<*foo{THING}> cannot. When in doubt, use C<*FH>. | |
822 | ||
823 | All functions that are capable of creating filehandles (open(), | |
824 | opendir(), pipe(), socketpair(), sysopen(), socket(), and accept()) | |
825 | automatically create an anonymous filehandle if the handle passed to | |
826 | them is an uninitialized scalar variable. This allows the constructs | |
827 | such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to | |
828 | create filehandles that will conveniently be closed automatically when | |
829 | the scope ends, provided there are no other references to them. This | |
830 | largely eliminates the need for typeglobs when opening filehandles | |
831 | that must be passed around, as in the following example: | |
832 | ||
833 | sub myopen { | |
834 | open my $fh, "@_" | |
835 | or die "Can't open '@_': $!"; | |
836 | return $fh; | |
837 | } | |
838 | ||
839 | { | |
840 | my $f = myopen("</etc/motd"); | |
841 | print <$f>; | |
842 | # $f implicitly closed here | |
843 | } | |
844 | ||
845 | Note that if an initialized scalar variable is used instead the | |
846 | result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent | |
847 | to C<open( *{'zzz'}, ...)>. | |
848 | C<use strict 'refs'> forbids such practice. | |
849 | ||
850 | Another way to create anonymous filehandles is with the Symbol | |
851 | module or with the IO::Handle module and its ilk. These modules | |
852 | have the advantage of not hiding different types of the same name | |
853 | during the local(). See the bottom of L<perlfunc/open()> for an | |
854 | example. | |
855 | ||
856 | =head1 SEE ALSO | |
857 | ||
858 | See L<perlvar> for a description of Perl's built-in variables and | |
859 | a discussion of legal variable names. See L<perlref>, L<perlsub>, | |
860 | and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and | |
861 | the C<*foo{THING}> syntax. |