[unix-history] / sys / i386 / stand / fdbootblk.c

/*-
 * Copyright (c) 1990 The Regents of the University of California.
 * All rights reserved.
 *
 * This code is derived from software contributed to Berkeley by
 * William Jolitz.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 * 3. All advertising materials mentioning features or use of this software
 *    must display the following acknowledgement:
 *	This product includes software developed by the University of
 *	California, Berkeley and its contributors.
 * 4. Neither the name of the University nor the names of its contributors
 *    may be used to endorse or promote products derived from this software
 *    without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 * SUCH DAMAGE.
 *
 *	@(#)fdbootblk.c	7.2 (Berkeley) 5/4/91
 */

/*
 * fdbootblk.s:
 *	Written 10/6/90 by William F. Jolitz
 *	Initial block boot for AT/386 with typical stupid NEC controller
 *
 *	Goal is to read in sucessive 7.5Kbytes of bootstrap to
 *	execute.
 *
 *	No attempt is made to handle disk errors.
 *
 * PATCHES MAGIC                LEVEL   PATCH THAT GOT US HERE
 * --------------------         -----   ----------------------
 * CURRENT PATCH LEVEL:         1       00073
 * --------------------         -----   ----------------------
 *
 * 22 Jan 93	Frank Maclachlan        Fixed NOP's to read correct register
 *
 */
/*#include "/sys/i386/isa/isa.h"
#include "/sys/i386/isa/fdreg.h"*/
#define	NOP	inb	$0x84,%al
#define BIOSRELOC	0x7c00
#define	start	RELOC+0x400

	/* mumbo-jumbo to pacify DOS, in the hope of getting diskcopy to work */
	jmp 1f
	.asciz "386BSD "
	.byte 1			# sectors per allocation
	.word 15		# additional sectors for bootstrap
	.word 0			# number of DOS fat sectors
	.word 0			# number of DOS rootdir entries
	.byte 0xf0		# media descriptor
	.word 0			# number of sectors per a DOS fat entry
	.word 18		# number of sectors per track
	.word 2			# number of heads
	.long 0			# number of hidden sectors
	.long 2880-18		# logical sectors per volume
	.byte 0			# physical drive
	.byte 0x29		# ?
	.long 137		# binary id
	.ascii "Release 0.1"	# volume label
	.space 5
1:
	/* step 0 force descriptors to bottom of address space */
	
	cli
	.byte 0xb8,0x30,0x00	/* mov $0x30,%ax */
	mov %ax, %ss
	.byte 0xbc,0x00,0x01	/* mov $0x100,%sp */

	xorl	%eax,%eax
	movl	%ax,%ds
	movl	%ax,%es

	/* obtain BIOS parameters for hard disk XXX */
	movb	$0x9f,%ah	 /* write to 0x9ff00  XXX */
	movb	$0xf0,%al
	mov	%ax,%es
	xor	%edi,%edi

	.byte 0xf, 0xb4, 0x36 ; .word  0x41*4	/* lfs 0x41*4, %si */
	xorb	%ch,%ch
	movb	$0x10,%cl
	fs
	rep
	movsb

	.byte 0xf, 0xb4, 0x36 ; .word  0x46*4	/* lfs 0x46*4, %si */
	xorb	%ch,%ch
	movb	$0x10,%cl
	fs
	rep
	movsb

 	xorl	%eax,%eax
	movl	%ax,%es

	/* step 1 load new descriptor table */

	.byte 0x2E,0x0F,1,0x16 /* word aword cs lgdt GDTptr */
	.word	BIOSRELOC+0xa4	#GDTptr

	/* step 2 turn on protected mode */

	smsw	%ax
	orb	$1,%al
	lmsw	%ax
	jmp	1f
	nop

	/* step 3  reload segment descriptors */

 1:
	xorl	%eax,%eax
	movb	$0x10,%al
	movl	%ax,%ds
	movl	%ax,%es
	movl	%ax,%ss
	word
	ljmp	$0x8,$ BIOSRELOC+0xb3	/* would be nice if .-RELOC+0x7c00 worked */

 /* Global Descriptor Table contains three descriptors:
  * 0x00: Null: not used
  * 0x08: Code: code segment starts at 0 and extents for 4 gigabytes
  * 0x10: Data: data segment starts at 0 and extends for 4 gigabytes
  *		(overlays code)
  */
GDT:
NullDesc:	.word	0,0,0,0	# null descriptor - not used
CodeDesc:	.word	0xFFFF	# limit at maximum: (bits 15:0)
	.byte	0,0,0	# base at 0: (bits 23:0)
	.byte	0x9f	# present/priv level 0/code/conforming/readable
	.byte	0xcf	# page granular/default 32-bit/limit(bits 19:16)
	.byte	0	# base at 0: (bits 31:24)
DataDesc:	.word	0xFFFF	# limit at maximum: (bits 15:0)
	.byte	0,0,0	# base at 0: (bits 23:0)
	.byte	0x93	# present/priv level 0/data/expand-up/writeable
	.byte	0xcf	# page granular/default 32-bit/limit(bits 19:16)
	.byte	0	# base at 0: (bits 31:24)

/* Global Descriptor Table pointer
 *  contains 6-byte pointer information for LGDT
 */
GDTptr:	.word	0x17	# limit to three 8 byte selectors(null,code,data)
	.long 	BIOSRELOC+0x8c	# GDT -- arrgh, gas again!
readcmd: .byte 0xe6,0,0,0,0,2,18,0x1b,0xff

	/* step 4 relocate to final bootstrap address. */
reloc:
	movl	$ BIOSRELOC,%esi
	movl	$ RELOC,%edi
	movl	$512,%ecx
	rep
	movsb
	movl	$0xa0000, %esp
	pushl	$dodisk
	ret

	/* step 5 load remaining 15 sectors off disk */
dodisk:
	movl	$ RELOC+0x200, %edi
	xorl	%ebx, %ebx
	incb	%bl # shl $1,%bl
	incb	%bl
	movb	$0x20,%al	# do a eoi
	outb	%al,$0x20

	NOP
	movb	$0xbf,%al	# enable floppy interrupt, mask out rest
	outb	%al,$0x21
	NOP
 8:
	movb	%bl,readcmd+4
	movl	%edi,%ecx

	/* Set read/write bytes */
	xorl	%edx,%edx
	movb	$0x0c,%dl	# outb(0xC,junk); outb(0xB,0x46);
	outb	%al,%dx		# reset DMA controller first/last flip-flop
	NOP
	decb	%dx
	movb	$0x46,%al	# single mode, write mem, chan 2
	outb	%al,%dx		# output DMA controller mode byte

	/* Send start address */
	movb	$0x04,%dl	# outb(0x4, addr);
	movb	%cl,%al
	outb	%al,%dx
	NOP
	movb	%ch,%al		# outb(0x4, addr>>8);
	outb	%al,%dx
	NOP
	rorl	$8,%ecx		# outb(0x81, addr>>16);
	movb	%ch,%al
	outb	%al,$0x81
	NOP

	/* Send count */
	movb	$0x05,%dl	# outb(0x5, 0);
	xorl	%eax,%eax
	outb	%al,%dx
	NOP
	movb	$2,%al		# outb(0x5,2);
	outb	%al,%dx
	NOP

	/* set channel 2 */
	movb	$2,%al		# outb(0x0A,2);
	outb	%al,$0x0A
	NOP

	/* issue read command to fdc */
	movw	$0x3f4,%dx
	movl	$readcmd,%esi
	xorl	%ecx,%ecx
	movb	$9,%cl

 2:	NOP
	inb	%dx,%al
	testb	$0x80,%al
	jz 2b

	incb	%dx
	NOP
	movl	(%esi),%al
	outb	%al,%dx
	NOP
	incl	%esi
	decb	%dx
	loop	 2b

	/* watch the icu looking for an interrupt signalling completion */
	xorl	%edx,%edx
	movb	$0x20,%dl
 2:
	NOP
	movb	$0xc,%al
	outb	%al,%dx
	NOP
	inb	%dx,%al
	andb	$0x7f,%al
	cmpb	$6,%al
	jne	2b
	NOP
	movb	$0x20,%al	# do a eoi
	outb	%al,%dx
	NOP

	movl	$0x3f4,%edx
	xorl	%ecx,%ecx
	movb	$7,%cl
 2:
	NOP
	inb	%dx,%al
	andb	$0xC0,%al
	cmpb	$0xc0,%al
	jne	2b
	incb	%dx
	inb	%dx,%al
	decb	%dx
	loop	2b

	/* extract the status bytes after the read. must we do this? */
	addw	$0x200,%edi	# next addr to load to
	incb	%bl
	cmpb	$15,%bl
	jle	8b
	
	/* for clever bootstrap, dig out boot unit and cylinder */
	pushl	$0
	pushl	$0
	
	/* fd controller is major device 2 */
	pushl	$2	/* dev */

	/* sorry, no flags at this point! */

	movl $ start, %eax
	call %eax	/* main (dev, unit, off) */

ebootblkcode:

	/* remaining space usable for a disk label */
	
	.org	0x1fe
	.word	0xaa55		/* signature -- used by BIOS ROM */

ebootblk: 			/* MUST BE EXACTLY 0x200 BIG FOR SURE */
Commit	Line	Data
15637ed4 RG	1	/*-
	2	* Copyright (c) 1990 The Regents of the University of California.
	3	* All rights reserved.
	4	*
	5	* This code is derived from software contributed to Berkeley by
	6	* William Jolitz.
	7	*
	8	* Redistribution and use in source and binary forms, with or without
	9	* modification, are permitted provided that the following conditions
	10	* are met:
	11	* 1. Redistributions of source code must retain the above copyright
	12	* notice, this list of conditions and the following disclaimer.
	13	* 2. Redistributions in binary form must reproduce the above copyright
	14	* notice, this list of conditions and the following disclaimer in the
	15	* documentation and/or other materials provided with the distribution.
	16	* 3. All advertising materials mentioning features or use of this software
	17	* must display the following acknowledgement:
	18	* This product includes software developed by the University of
	19	* California, Berkeley and its contributors.
	20	* 4. Neither the name of the University nor the names of its contributors
	21	* may be used to endorse or promote products derived from this software
	22	* without specific prior written permission.
	23	*
	24	* THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
	25	* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
	26	* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
	27	* ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
	28	* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
	29	* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
	30	* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
	31	* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
	32	* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
	33	* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
	34	* SUCH DAMAGE.
	35	*
	36	* @(#)fdbootblk.c 7.2 (Berkeley) 5/4/91
	37	*/
	38
	39	/*
	40	* fdbootblk.s:
	41	* Written 10/6/90 by William F. Jolitz
	42	* Initial block boot for AT/386 with typical stupid NEC controller
	43	*
	44	* Goal is to read in sucessive 7.5Kbytes of bootstrap to
	45	* execute.
	46	*
	47	* No attempt is made to handle disk errors.
	48	*
	49	* PATCHES MAGIC LEVEL PATCH THAT GOT US HERE
	50	* -------------------- ----- ----------------------
	51	* CURRENT PATCH LEVEL: 1 00073
	52	* -------------------- ----- ----------------------
	53	*
	54	* 22 Jan 93 Frank Maclachlan Fixed NOP's to read correct register
	55	*
	56	*/
	57	/*#include "/sys/i386/isa/isa.h"
	58	#include "/sys/i386/isa/fdreg.h"*/
	59	#define NOP inb $0x84,%al
	60	#define BIOSRELOC 0x7c00
	61	#define start RELOC+0x400
	62
	63	/* mumbo-jumbo to pacify DOS, in the hope of getting diskcopy to work */
	64	jmp 1f
65	.asciz "386BSD "
66	.byte 1 # sectors per allocation
67	.word 15 # additional sectors for bootstrap
68	.word 0 # number of DOS fat sectors
69	.word 0 # number of DOS rootdir entries
70	.byte 0xf0 # media descriptor
71	.word 0 # number of sectors per a DOS fat entry
72	.word 18 # number of sectors per track
73	.word 2 # number of heads
74	.long 0 # number of hidden sectors
75	.long 2880-18 # logical sectors per volume
76	.byte 0 # physical drive
77	.byte 0x29 # ?
78	.long 137 # binary id
79	.ascii "Release 0.1" # volume label
80	.space 5
81	1:
82	/* step 0 force descriptors to bottom of address space */
83
84	cli
85	.byte 0xb8,0x30,0x00 /* mov $0x30,%ax */
86	mov %ax, %ss
87	.byte 0xbc,0x00,0x01 /* mov $0x100,%sp */
88
89	xorl %eax,%eax
90	movl %ax,%ds
91	movl %ax,%es
92
93	/* obtain BIOS parameters for hard disk XXX */
94	movb $0x9f,%ah /* write to 0x9ff00 XXX */
95	movb $0xf0,%al
96	mov %ax,%es
97	xor %edi,%edi
98
99	.byte 0xf, 0xb4, 0x36 ; .word 0x414 / lfs 0x414, %si /
100	xorb %ch,%ch
101	movb $0x10,%cl
102	fs
103	rep
104	movsb
105
106	.byte 0xf, 0xb4, 0x36 ; .word 0x464 / lfs 0x464, %si /
107	xorb %ch,%ch
108	movb $0x10,%cl
109	fs
110	rep
111	movsb
112
113	xorl %eax,%eax
114	movl %ax,%es
115
116	/* step 1 load new descriptor table */
117
118	.byte 0x2E,0x0F,1,0x16 /* word aword cs lgdt GDTptr */
119	.word BIOSRELOC+0xa4 #GDTptr
120
121	/* step 2 turn on protected mode */
122
123	smsw %ax
124	orb $1,%al
125	lmsw %ax
126	jmp 1f
127	nop
128
129	/* step 3 reload segment descriptors */
130
131	1:
132	xorl %eax,%eax
133	movb $0x10,%al
134	movl %ax,%ds
135	movl %ax,%es
136	movl %ax,%ss
137	word
138	ljmp $0x8,$ BIOSRELOC+0xb3 /* would be nice if .-RELOC+0x7c00 worked */
139
140	/* Global Descriptor Table contains three descriptors:
141	* 0x00: Null: not used
142	* 0x08: Code: code segment starts at 0 and extents for 4 gigabytes
143	* 0x10: Data: data segment starts at 0 and extends for 4 gigabytes
144	* (overlays code)
145	*/
146	GDT:
147	NullDesc: .word 0,0,0,0 # null descriptor - not used
148	CodeDesc: .word 0xFFFF # limit at maximum: (bits 15:0)
149	.byte 0,0,0 # base at 0: (bits 23:0)
150	.byte 0x9f # present/priv level 0/code/conforming/readable
151	.byte 0xcf # page granular/default 32-bit/limit(bits 19:16)
152	.byte 0 # base at 0: (bits 31:24)
153	DataDesc: .word 0xFFFF # limit at maximum: (bits 15:0)
154	.byte 0,0,0 # base at 0: (bits 23:0)
155	.byte 0x93 # present/priv level 0/data/expand-up/writeable
156	.byte 0xcf # page granular/default 32-bit/limit(bits 19:16)
157	.byte 0 # base at 0: (bits 31:24)
158
159	/* Global Descriptor Table pointer
160	* contains 6-byte pointer information for LGDT
161	*/
162	GDTptr: .word 0x17 # limit to three 8 byte selectors(null,code,data)
163	.long BIOSRELOC+0x8c # GDT -- arrgh, gas again!
164	readcmd: .byte 0xe6,0,0,0,0,2,18,0x1b,0xff
165
166	/* step 4 relocate to final bootstrap address. */
167	reloc:
168	movl $ BIOSRELOC,%esi
169	movl $ RELOC,%edi
170	movl $512,%ecx
171	rep
172	movsb
173	movl $0xa0000, %esp
174	pushl $dodisk
175	ret
176
177	/* step 5 load remaining 15 sectors off disk */
178	dodisk:
179	movl $ RELOC+0x200, %edi
180	xorl %ebx, %ebx
181	incb %bl # shl $1,%bl
182	incb %bl
183	movb $0x20,%al # do a eoi
184	outb %al,$0x20
185
186	NOP
187	movb $0xbf,%al # enable floppy interrupt, mask out rest
188	outb %al,$0x21
189	NOP
190	8:
191	movb %bl,readcmd+4
192	movl %edi,%ecx
193
194	/* Set read/write bytes */
195	xorl %edx,%edx
196	movb $0x0c,%dl # outb(0xC,junk); outb(0xB,0x46);
197	outb %al,%dx # reset DMA controller first/last flip-flop
198	NOP
199	decb %dx
200	movb $0x46,%al # single mode, write mem, chan 2
201	outb %al,%dx # output DMA controller mode byte
202
203	/* Send start address */
204	movb $0x04,%dl # outb(0x4, addr);
205	movb %cl,%al
206	outb %al,%dx
207	NOP
208	movb %ch,%al # outb(0x4, addr>>8);
209	outb %al,%dx
210	NOP
211	rorl $8,%ecx # outb(0x81, addr>>16);
212	movb %ch,%al
213	outb %al,$0x81
214	NOP
215
216	/* Send count */
217	movb $0x05,%dl # outb(0x5, 0);
218	xorl %eax,%eax
219	outb %al,%dx
220	NOP
221	movb $2,%al # outb(0x5,2);
222	outb %al,%dx
223	NOP
224
225	/* set channel 2 */
226	movb $2,%al # outb(0x0A,2);
227	outb %al,$0x0A
228	NOP
229
230	/* issue read command to fdc */
231	movw $0x3f4,%dx
232	movl $readcmd,%esi
233	xorl %ecx,%ecx
234	movb $9,%cl
235
236	2: NOP
237	inb %dx,%al
238	testb $0x80,%al
239	jz 2b
240
241	incb %dx
242	NOP
243	movl (%esi),%al
244	outb %al,%dx
245	NOP
246	incl %esi
247	decb %dx
248	loop 2b
249
250	/* watch the icu looking for an interrupt signalling completion */
251	xorl %edx,%edx
252	movb $0x20,%dl
253	2:
254	NOP
255	movb $0xc,%al
256	outb %al,%dx
257	NOP
258	inb %dx,%al
259	andb $0x7f,%al
260	cmpb $6,%al
261	jne 2b
262	NOP
263	movb $0x20,%al # do a eoi
264	outb %al,%dx
265	NOP
266
267	movl $0x3f4,%edx
268	xorl %ecx,%ecx
269	movb $7,%cl
270	2:
271	NOP
272	inb %dx,%al
273	andb $0xC0,%al
274	cmpb $0xc0,%al
275	jne 2b
276	incb %dx
277	inb %dx,%al
278	decb %dx
279	loop 2b
280
281	/* extract the status bytes after the read. must we do this? */
282	addw $0x200,%edi # next addr to load to
283	incb %bl
284	cmpb $15,%bl
285	jle 8b
286
287	/* for clever bootstrap, dig out boot unit and cylinder */
288	pushl $0
289	pushl $0
290
291	/* fd controller is major device 2 */
292	pushl $2 /* dev */
293
294	/* sorry, no flags at this point! */
295
296	movl $ start, %eax
297	call %eax /* main (dev, unit, off) */
298
299	ebootblkcode:
300
301	/* remaining space usable for a disk label */
302
303	.org 0x1fe
304	.word 0xaa55 /* signature -- used by BIOS ROM */
305
306	ebootblk: /* MUST BE EXACTLY 0x200 BIG FOR SURE */