[unix-history] / sys / i386 / boot / start.S

/*
 * Mach Operating System
 * Copyright (c) 1992, 1991 Carnegie Mellon University
 * All Rights Reserved.
 * 
 * Permission to use, copy, modify and distribute this software and its
 * documentation is hereby granted, provided that both the copyright
 * notice and this permission notice appear in all copies of the
 * software, derivative works or modified versions, and any portions
 * thereof, and that both notices appear in supporting documentation.
 * 
 * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
 * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
 * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
 * 
 * Carnegie Mellon requests users of this software to return to
 * 
 *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
 *  School of Computer Science
 *  Carnegie Mellon University
 *  Pittsburgh PA 15213-3890
 * 
 * any improvements or extensions that they make and grant Carnegie Mellon
 * the rights to redistribute these changes.
 *
 *	from: Mach, Revision 2.2  92/04/04  11:36:29  rpd
 *	$Id: start.S,v 1.2 1993/10/16 19:11:38 rgrimes Exp $
 */

/*
  Copyright 1988, 1989, 1990, 1991, 1992 
   by Intel Corporation, Santa Clara, California.

                All Rights Reserved

Permission to use, copy, modify, and distribute this software and
its documentation for any purpose and without fee is hereby
granted, provided that the above copyright notice appears in all
copies and that both the copyright notice and this permission notice
appear in supporting documentation, and that the name of Intel
not be used in advertising or publicity pertaining to distribution
of the software without specific, written prior permission.

INTEL DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE
INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS,
IN NO EVENT SHALL INTEL BE LIABLE FOR ANY SPECIAL, INDIRECT, OR
CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
LOSS OF USE, DATA OR PROFITS, WHETHER IN ACTION OF CONTRACT,
NEGLIGENCE, OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
*/
#include	"asm.h"

	.file	"start.s"

BOOTSEG		=	0x9000	# boot will be loaded here (below 640K)
BOOTSTACK	=	0xe000	# boot stack
SIGNATURE	=	0xaa55
LOADSZ		=	15	# size of unix boot
PARTSTART	=	0x1be	# starting address of partition table
NUMPART		=	4	# number of partitions in partition table
PARTSZ		=	16	# each partition table entry is 16 bytes
BSDPART		=	0xA5	# value of boot_ind, means bootable partition
BOOTABLE	=	0x80	# value of boot_ind, means bootable partition

	.text	

ENTRY(boot1)
	# start (aka boot1) is loaded at 0x0:0x7c00 but we want 0x7c0:0
	# ljmp to the next instruction to adjust %cs
	data32
	ljmp $0x7c0, $start

start:
	# set up %ds
	mov	%cs, %ax
	mov	%ax, %ds

	# set up %ss and %esp
	data32
	mov	$BOOTSEG, %eax
	mov	%ax, %ss
	data32
	mov	$BOOTSTACK, %esp

	/*** set up %es, (where we will load boot2 to) ***/
	mov	%ax, %es

#ifdef	DEBUG
	data32
	mov	$one, %esi
	data32
	call	message
#endif

	# bootstrap passes us drive number in %dl
	cmpb	$0x80, %dl
	data32
	jae	hd

fd:
	mov	$0x0, %dl
#	reset the disk system
#ifdef	DEBUG
	data32
	mov	$two, %esi
	data32
	call	message
#endif
	movb	$0x0, %ah
	int	$0x13
	data32
	mov	$0x0001, %ecx	# cyl 0, sector 1
	movb	$0, %dh		# head
#ifdef	DEBUG
	data32
	mov	$three, %esi
	data32
	call	message
#endif
	data32
	jmp	load

hd:	/**** load sector 0 into the BOOTSEG ****/
#ifdef	DEBUG
	data32
	mov	$four, %esi
	data32
	call	message
#endif
	data32
	mov	$0x0201, %eax
	xor	%ebx, %ebx	# %bx = 0
	data32
	mov	$0x0001, %ecx
#ifdef	DEBUG
	data32
	mov	$five, %esi
	data32
	call	message
#endif
	data32
	andl	$0xff, %edx
	/*mov	$0x0080, %edx*/
	int	$0x13
	data32
	jb	read_error

	/***# find the first 386BSD partition *****/
	data32
	mov	$PARTSTART, %ebx
	data32
	mov	$NUMPART, %ecx
again:
	addr32
	movb    %es:4(%ebx), %al
	cmpb	$BSDPART, %al
	data32
	je	found
	data32
	add	$PARTSZ, %ebx
	data32
	loop	again
	data32
	mov	$enoboot, %esi
	data32
	jmp	err_stop


/*
# BIOS call "INT 0x13 Function 0x2" to read sectors from disk into memory
#       Call with       %ah = 0x2
#                       %al = number of sectors
#                       %ch = cylinder
#                       %cl = sector
#                       %dh = head
#                       %dl = drive (0x80 for hard disk, 0x0 for floppy disk)
#                       %es:%bx = segment:offset of buffer
#       Return:
#                       %al = 0x0 on success; err code on failure
*/

found:
	addr32
	movb	%es:1(%ebx), %dh /* head */
	addr32
	movl	%es:2(%ebx), %ecx /*sect, cyl (+ 2 bytes junk in top word) */

load:
	movb	$0x2, %ah	/* function 2 */
	movb	$LOADSZ, %al	/* number of blocks */
	xor	%ebx, %ebx	/* %bx = 0, put it at 0 in the BOOTSEG */
	int	$0x13
	data32
	jb	read_error

	# ljmp to the second stage boot loader (boot2).
	# After ljmp, %cs is BOOTSEG and boot1 (512 bytes) will be used
	# as an internal buffer "intbuf".

#ifdef	DEBUG
	data32
	mov	$six, %esi
	data32
	call	message
#endif
	data32
	ljmp	$BOOTSEG, $ EXT(boot2)

#
#	read_error
#

read_error:
	data32
	mov	$eread, %esi
err_stop:
	data32
	call	message
	data32
	jmp	stop

#
#	message: write the error message in %ds:%esi to console
#

message:
/*
	# Use BIOS "int 10H Function 0Eh" to write character in teletype mode
	#	%ah = 0xe	%al = character
	#	%bh = page	%bl = foreground color (graphics modes)
*/

	data32
	push	%eax
	data32
	push	%ebx
	data32
	mov	$0x0001, %ebx
	cld

nextb:
	lodsb			# load a byte into %al
	cmpb	$0x0, %al
	data32
	je	done
	movb	$0xe, %ah
	int	$0x10		# display a byte
	data32
	jmp	nextb
done:
	data32
	pop	%ebx
	data32
	pop	%eax
	data32
	ret

stop:	hlt
	data32
	jmp	stop		# halt doesnt actually halt forever

/* error messages */

#ifdef	DEBUG
one:	String		"1\r\n\0"
two:	String		"2\r\n\0"
three:	String		"3\r\n\0"
four:	String		"4\r\n\0"
five:	String		"5\r\n\0"
six:	String		"6\r\n\0"
seven:	String		"7\r\n\0"
#endif	DEBUG
eread:	String		"Read error\r\n\0"
enoboot: String		"No bootable partition\r\n\0"
endofcode:
/* throw in a partition in case we are block0 as well */
/* flag, head, sec, cyl, typ, ehead, esect, ecyl, start, len */
	. = EXT(boot1) + PARTSTART
	.byte 0x0,0,0,0,0,0,0,0
	.long 0,0
	.byte 0x0,0,0,0,0,0,0,0
	.long 0,0
	.byte 0x0,0,0,0,0,0,0,0
	.long 0,0
	.byte BOOTABLE,0,1,0,BSDPART,255,255,255
	.long 0,50000
/* the last 2 bytes in the sector 0 contain the signature */
	. = EXT(boot1) + 0x1fe
	.value	SIGNATURE
ENTRY(disklabel)
	. = EXT(boot1) + 0x400
Commit	Line	Data
a27f4645	1	/*
a27f4645 RM	2	* Mach Operating System
	3	* Copyright (c) 1992, 1991 Carnegie Mellon University
	4	* All Rights Reserved.
	5	*
	6	* Permission to use, copy, modify and distribute this software and its
	7	* documentation is hereby granted, provided that both the copyright
	8	* notice and this permission notice appear in all copies of the
	9	* software, derivative works or modified versions, and any portions
	10	* thereof, and that both notices appear in supporting documentation.
	11	*
	12	* CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
	13	* CONDITION. CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
	14	* ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
	15	*
	16	* Carnegie Mellon requests users of this software to return to
	17	*
	18	* Software Distribution Coordinator or Software.Distribution@CS.CMU.EDU
	19	* School of Computer Science
	20	* Carnegie Mellon University
	21	* Pittsburgh PA 15213-3890
	22	*
	23	* any improvements or extensions that they make and grant Carnegie Mellon
	24	* the rights to redistribute these changes.
a27f4645	25	*
e4270b63	26	* from: Mach, Revision 2.2 92/04/04 11:36:29 rpd
d1531e51	27	* $Id: start.S,v 1.2 1993/10/16 19:11:38 rgrimes Exp $
a27f4645	28	*/
a27f4645 RM	29
	30	/*
	31	Copyright 1988, 1989, 1990, 1991, 1992
	32	by Intel Corporation, Santa Clara, California.
	33
	34	All Rights Reserved
	35
	36	Permission to use, copy, modify, and distribute this software and
	37	its documentation for any purpose and without fee is hereby
	38	granted, provided that the above copyright notice appears in all
	39	copies and that both the copyright notice and this permission notice
	40	appear in supporting documentation, and that the name of Intel
	41	not be used in advertising or publicity pertaining to distribution
	42	of the software without specific, written prior permission.
	43
	44	INTEL DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE
	45	INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS,
	46	IN NO EVENT SHALL INTEL BE LIABLE FOR ANY SPECIAL, INDIRECT, OR
	47	CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
	48	LOSS OF USE, DATA OR PROFITS, WHETHER IN ACTION OF CONTRACT,
	49	NEGLIGENCE, OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
	50	WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
	51	*/
	52	#include "asm.h"
	53
	54	.file "start.s"
	55
	56	BOOTSEG = 0x9000 # boot will be loaded here (below 640K)
	57	BOOTSTACK = 0xe000 # boot stack
	58	SIGNATURE = 0xaa55
	59	LOADSZ = 15 # size of unix boot
	60	PARTSTART = 0x1be # starting address of partition table
	61	NUMPART = 4 # number of partitions in partition table
	62	PARTSZ = 16 # each partition table entry is 16 bytes
	63	BSDPART = 0xA5 # value of boot_ind, means bootable partition
	64	BOOTABLE = 0x80 # value of boot_ind, means bootable partition
	65
	66	.text
	67
	68	ENTRY(boot1)
	69	# start (aka boot1) is loaded at 0x0:0x7c00 but we want 0x7c0:0
	70	# ljmp to the next instruction to adjust %cs
	71	data32
	72	ljmp $0x7c0, $start
	73
	74	start:
	75	# set up %ds
	76	mov %cs, %ax
	77	mov %ax, %ds
	78
	79	# set up %ss and %esp
	80	data32
	81	mov $BOOTSEG, %eax
	82	mov %ax, %ss
	83	data32
	84	mov $BOOTSTACK, %esp
	85
	86	/* set up %es, (where we will load boot2 to) */
	87	mov %ax, %es
	88
	89	#ifdef DEBUG
	90	data32
	91	mov $one, %esi
	92	data32
93	call message
94	#endif
95
96	# bootstrap passes us drive number in %dl
97	cmpb $0x80, %dl
98	data32
99	jae hd
100
101	fd:
d1531e51	102	mov $0x0, %dl
a27f4645 RM	103	# reset the disk system
	104	#ifdef DEBUG
	105	data32
	106	mov $two, %esi
	107	data32
	108	call message
	109	#endif
	110	movb $0x0, %ah
	111	int $0x13
	112	data32
	113	mov $0x0001, %ecx # cyl 0, sector 1
	114	movb $0, %dh # head
	115	#ifdef DEBUG
	116	data32
	117	mov $three, %esi
	118	data32
	119	call message
	120	#endif
	121	data32
	122	jmp load
	123
	124	hd: /** load sector 0 into the BOOTSEG **/
	125	#ifdef DEBUG
	126	data32
	127	mov $four, %esi
	128	data32
	129	call message
	130	#endif
	131	data32
	132	mov $0x0201, %eax
	133	xor %ebx, %ebx # %bx = 0
	134	data32
	135	mov $0x0001, %ecx
	136	#ifdef DEBUG
	137	data32
	138	mov $five, %esi
	139	data32
	140	call message
	141	#endif
	142	data32
	143	andl $0xff, %edx
	144	/mov $0x0080, %edx/
	145	int $0x13
	146	data32
	147	jb read_error
	148
	149	/*# find the first 386BSD partition ***/
	150	data32
	151	mov $PARTSTART, %ebx
	152	data32
	153	mov $NUMPART, %ecx
	154	again:
	155	addr32
	156	movb %es:4(%ebx), %al
	157	cmpb $BSDPART, %al
	158	data32
	159	je found
	160	data32
	161	add $PARTSZ, %ebx
	162	data32
	163	loop again
	164	data32
	165	mov $enoboot, %esi
	166	data32
167	jmp err_stop
168
169
170	/*
171	# BIOS call "INT 0x13 Function 0x2" to read sectors from disk into memory
172	# Call with %ah = 0x2
173	# %al = number of sectors
174	# %ch = cylinder
175	# %cl = sector
176	# %dh = head
177	# %dl = drive (0x80 for hard disk, 0x0 for floppy disk)
178	# %es:%bx = segment:offset of buffer
179	# Return:
180	# %al = 0x0 on success; err code on failure
181	*/
182
183	found:
184	addr32
185	movb %es:1(%ebx), %dh /* head */
186	addr32
187	movl %es:2(%ebx), %ecx /sect, cyl (+ 2 bytes junk in top word) /
188
189	load:
190	movb $0x2, %ah /* function 2 */
191	movb $LOADSZ, %al /* number of blocks */
192	xor %ebx, %ebx /* %bx = 0, put it at 0 in the BOOTSEG */
193	int $0x13
194	data32
195	jb read_error
196
197	# ljmp to the second stage boot loader (boot2).
198	# After ljmp, %cs is BOOTSEG and boot1 (512 bytes) will be used
199	# as an internal buffer "intbuf".
200
201	#ifdef DEBUG
202	data32
203	mov $six, %esi
204	data32
205	call message
206	#endif
207	data32
208	ljmp $BOOTSEG, $ EXT(boot2)
209
210	#
211	# read_error
212	#
213
214	read_error:
215	data32
216	mov $eread, %esi
217	err_stop:
218	data32
219	call message
220	data32
221	jmp stop
222
223	#
224	# message: write the error message in %ds:%esi to console
225	#
226
227	message:
228	/*
229	# Use BIOS "int 10H Function 0Eh" to write character in teletype mode
230	# %ah = 0xe %al = character
231	# %bh = page %bl = foreground color (graphics modes)
232	*/
233
234	data32
235	push %eax
236	data32
237	push %ebx
238	data32
239	mov $0x0001, %ebx
240	cld
241
242	nextb:
243	lodsb # load a byte into %al
244	cmpb $0x0, %al
245	data32
246	je done
247	movb $0xe, %ah
248	int $0x10 # display a byte
249	data32
250	jmp nextb
251	done:
252	data32
253	pop %ebx
254	data32
255	pop %eax
256	data32
257	ret
258
259	stop: hlt
260	data32
261	jmp stop # halt doesnt actually halt forever
262
263	/* error messages */
264
265	#ifdef DEBUG
266	one: String "1\r\n\0"
267	two: String "2\r\n\0"
268	three: String "3\r\n\0"
269	four: String "4\r\n\0"
270	five: String "5\r\n\0"
271	six: String "6\r\n\0"
272	seven: String "7\r\n\0"
273	#endif DEBUG
274	eread: String "Read error\r\n\0"
275	enoboot: String "No bootable partition\r\n\0"
276	endofcode:
277	/* throw in a partition in case we are block0 as well */
278	/* flag, head, sec, cyl, typ, ehead, esect, ecyl, start, len */
279	. = EXT(boot1) + PARTSTART
280	.byte 0x0,0,0,0,0,0,0,0
281	.long 0,0
282	.byte 0x0,0,0,0,0,0,0,0
283	.long 0,0
284	.byte 0x0,0,0,0,0,0,0,0
285	.long 0,0
286	.byte BOOTABLE,0,1,0,BSDPART,255,255,255
287	.long 0,50000
288	/* the last 2 bytes in the sector 0 contain the signature */
289	. = EXT(boot1) + 0x1fe
290	.value SIGNATURE
291	ENTRY(disklabel)
292	. = EXT(boot1) + 0x400