| 1 | /*- |
| 2 | * Copyright (c) 1991 The Regents of the University of California. |
| 3 | * All rights reserved. |
| 4 | * |
| 5 | * This module is believed to contain source code proprietary to AT&T. |
| 6 | * Use and redistribution is subject to the Berkeley Software License |
| 7 | * Agreement and your Software Agreement with AT&T (Western Electric). |
| 8 | */ |
| 9 | |
| 10 | %token FIRSTTOKEN /*must be first*/ |
| 11 | %token FINAL FATAL |
| 12 | %token LT LE GT GE EQ NE |
| 13 | %token MATCH NOTMATCH |
| 14 | %token APPEND |
| 15 | %token ADD MINUS MULT DIVIDE MOD UMINUS |
| 16 | %token ASSIGN ADDEQ SUBEQ MULTEQ DIVEQ MODEQ |
| 17 | %token JUMP |
| 18 | %token XBEGIN XEND |
| 19 | %token NL |
| 20 | %token PRINT PRINTF SPRINTF SPLIT |
| 21 | %token IF ELSE WHILE FOR IN NEXT EXIT BREAK CONTINUE |
| 22 | %token PROGRAM PASTAT PASTAT2 |
| 23 | |
| 24 | %right ASGNOP |
| 25 | %left BOR |
| 26 | %left AND |
| 27 | %left NOT |
| 28 | %left NUMBER VAR ARRAY FNCN SUBSTR LSUBSTR INDEX |
| 29 | %left GETLINE |
| 30 | %nonassoc RELOP MATCHOP |
| 31 | %left OR |
| 32 | %left STRING DOT CCL NCCL CHAR |
| 33 | %left '(' '^' '$' |
| 34 | %left CAT |
| 35 | %left '+' '-' |
| 36 | %left '*' '/' '%' |
| 37 | %left STAR PLUS QUEST |
| 38 | %left POSTINCR PREINCR POSTDECR PREDECR INCR DECR |
| 39 | %left FIELD INDIRECT |
| 40 | %token LASTTOKEN /* has to be last */ |
| 41 | |
| 42 | %{ |
| 43 | #ifndef lint |
| 44 | static char sccsid[] = "@(#)awk.g.y 4.4 (Berkeley) 4/27/91"; |
| 45 | #endif /* not lint */ |
| 46 | |
| 47 | #include "awk.def" |
| 48 | #ifndef DEBUG |
| 49 | # define PUTS(x) |
| 50 | #endif |
| 51 | %} |
| 52 | %% |
| 53 | |
| 54 | program: |
| 55 | begin pa_stats end { if (errorflag==0) winner = (node *)stat3(PROGRAM, $1, $2, $3); } |
| 56 | | error { yyclearin; yyerror("bailing out"); } |
| 57 | ; |
| 58 | |
| 59 | begin: |
| 60 | XBEGIN '{' stat_list '}' { PUTS("XBEGIN list"); $$ = $3; } |
| 61 | | begin NL |
| 62 | | { PUTS("empty XBEGIN"); $$ = (hack)nullstat; } |
| 63 | ; |
| 64 | |
| 65 | end: |
| 66 | XEND '{' stat_list '}' { PUTS("XEND list"); $$ = $3; } |
| 67 | | end NL |
| 68 | | { PUTS("empty END"); $$ = (hack)nullstat; } |
| 69 | ; |
| 70 | |
| 71 | compound_conditional: |
| 72 | conditional BOR conditional { PUTS("cond||cond"); $$ = op2(BOR, $1, $3); } |
| 73 | | conditional AND conditional { PUTS("cond&&cond"); $$ = op2(AND, $1, $3); } |
| 74 | | NOT conditional { PUTS("!cond"); $$ = op1(NOT, $2); } |
| 75 | | '(' compound_conditional ')' { $$ = $2; } |
| 76 | ; |
| 77 | |
| 78 | compound_pattern: |
| 79 | pattern BOR pattern { PUTS("pat||pat"); $$ = op2(BOR, $1, $3); } |
| 80 | | pattern AND pattern { PUTS("pat&&pat"); $$ = op2(AND, $1, $3); } |
| 81 | | NOT pattern { PUTS("!pat"); $$ = op1(NOT, $2); } |
| 82 | | '(' compound_pattern ')' { $$ = $2; } |
| 83 | ; |
| 84 | |
| 85 | conditional: |
| 86 | expr { PUTS("expr"); $$ = op2(NE, $1, valtonode(lookup("$zero&null", symtab, 0), CCON)); } |
| 87 | | rel_expr { PUTS("relexpr"); } |
| 88 | | lex_expr { PUTS("lexexpr"); } |
| 89 | | compound_conditional { PUTS("compcond"); } |
| 90 | ; |
| 91 | |
| 92 | else: |
| 93 | ELSE optNL { PUTS("else"); } |
| 94 | ; |
| 95 | |
| 96 | field: |
| 97 | FIELD { PUTS("field"); $$ = valtonode($1, CFLD); } |
| 98 | | INDIRECT term { PUTS("ind field"); $$ = op1(INDIRECT, $2); } |
| 99 | ; |
| 100 | |
| 101 | if: |
| 102 | IF '(' conditional ')' optNL { PUTS("if(cond)"); $$ = $3; } |
| 103 | ; |
| 104 | |
| 105 | lex_expr: |
| 106 | expr MATCHOP regular_expr { PUTS("expr~re"); $$ = op2($2, $1, makedfa($3)); } |
| 107 | | '(' lex_expr ')' { PUTS("(lex_expr)"); $$ = $2; } |
| 108 | ; |
| 109 | |
| 110 | var: |
| 111 | NUMBER {PUTS("number"); $$ = valtonode($1, CCON); } |
| 112 | | STRING { PUTS("string"); $$ = valtonode($1, CCON); } |
| 113 | | VAR { PUTS("var"); $$ = valtonode($1, CVAR); } |
| 114 | | VAR '[' expr ']' { PUTS("array[]"); $$ = op2(ARRAY, $1, $3); } |
| 115 | | field |
| 116 | ; |
| 117 | term: |
| 118 | var |
| 119 | | GETLINE { PUTS("getline"); $$ = op1(GETLINE, 0); } |
| 120 | | FNCN { PUTS("func"); |
| 121 | $$ = op2(FNCN, $1, valtonode(lookup("$record", symtab, 0), CFLD)); |
| 122 | } |
| 123 | | FNCN '(' ')' { PUTS("func()"); |
| 124 | $$ = op2(FNCN, $1, valtonode(lookup("$record", symtab, 0), CFLD)); |
| 125 | } |
| 126 | | FNCN '(' expr ')' { PUTS("func(expr)"); $$ = op2(FNCN, $1, $3); } |
| 127 | | SPRINTF print_list { PUTS("sprintf"); $$ = op1($1, $2); } |
| 128 | | SUBSTR '(' expr ',' expr ',' expr ')' |
| 129 | { PUTS("substr(e,e,e)"); $$ = op3(SUBSTR, $3, $5, $7); } |
| 130 | | SUBSTR '(' expr ',' expr ')' |
| 131 | { PUTS("substr(e,e,e)"); $$ = op3(SUBSTR, $3, $5, nullstat); } |
| 132 | | SPLIT '(' expr ',' VAR ',' expr ')' |
| 133 | { PUTS("split(e,e,e)"); $$ = op3(SPLIT, $3, $5, $7); } |
| 134 | | SPLIT '(' expr ',' VAR ')' |
| 135 | { PUTS("split(e,e,e)"); $$ = op3(SPLIT, $3, $5, nullstat); } |
| 136 | | INDEX '(' expr ',' expr ')' |
| 137 | { PUTS("index(e,e)"); $$ = op2(INDEX, $3, $5); } |
| 138 | | '(' expr ')' {PUTS("(expr)"); $$ = $2; } |
| 139 | | term '+' term { PUTS("t+t"); $$ = op2(ADD, $1, $3); } |
| 140 | | term '-' term { PUTS("t-t"); $$ = op2(MINUS, $1, $3); } |
| 141 | | term '*' term { PUTS("t*t"); $$ = op2(MULT, $1, $3); } |
| 142 | | term '/' term { PUTS("t/t"); $$ = op2(DIVIDE, $1, $3); } |
| 143 | | term '%' term { PUTS("t%t"); $$ = op2(MOD, $1, $3); } |
| 144 | | '-' term %prec QUEST { PUTS("-term"); $$ = op1(UMINUS, $2); } |
| 145 | | '+' term %prec QUEST { PUTS("+term"); $$ = $2; } |
| 146 | | INCR var { PUTS("++var"); $$ = op1(PREINCR, $2); } |
| 147 | | DECR var { PUTS("--var"); $$ = op1(PREDECR, $2); } |
| 148 | | var INCR { PUTS("var++"); $$= op1(POSTINCR, $1); } |
| 149 | | var DECR { PUTS("var--"); $$= op1(POSTDECR, $1); } |
| 150 | ; |
| 151 | |
| 152 | expr: |
| 153 | term { PUTS("term"); } |
| 154 | | expr term { PUTS("expr term"); $$ = op2(CAT, $1, $2); } |
| 155 | | var ASGNOP expr { PUTS("var=expr"); $$ = stat2($2, $1, $3); } |
| 156 | ; |
| 157 | |
| 158 | optNL: |
| 159 | NL |
| 160 | | |
| 161 | ; |
| 162 | |
| 163 | pa_stat: |
| 164 | pattern { PUTS("pattern"); $$ = stat2(PASTAT, $1, genprint()); } |
| 165 | | pattern '{' stat_list '}' { PUTS("pattern {...}"); $$ = stat2(PASTAT, $1, $3); } |
| 166 | | pattern ',' pattern { PUTS("srch,srch"); $$ = pa2stat($1, $3, genprint()); } |
| 167 | | pattern ',' pattern '{' stat_list '}' |
| 168 | { PUTS("srch, srch {...}"); $$ = pa2stat($1, $3, $5); } |
| 169 | | '{' stat_list '}' { PUTS("null pattern {...}"); $$ = stat2(PASTAT, nullstat, $2); } |
| 170 | ; |
| 171 | |
| 172 | pa_stats: |
| 173 | pa_stats pa_stat st { PUTS("pa_stats pa_stat"); $$ = linkum($1, $2); } |
| 174 | | { PUTS("null pa_stat"); $$ = (hack)nullstat; } |
| 175 | | pa_stats pa_stat {PUTS("pa_stats pa_stat"); $$ = linkum($1, $2); } |
| 176 | ; |
| 177 | |
| 178 | pattern: |
| 179 | regular_expr { PUTS("regex"); |
| 180 | $$ = op2(MATCH, valtonode(lookup("$record", symtab, 0), CFLD), makedfa($1)); |
| 181 | } |
| 182 | | rel_expr { PUTS("relexpr"); } |
| 183 | | lex_expr { PUTS("lexexpr"); } |
| 184 | | compound_pattern { PUTS("comp pat"); } |
| 185 | ; |
| 186 | |
| 187 | print_list: |
| 188 | expr { PUTS("expr"); } |
| 189 | | pe_list { PUTS("pe_list"); } |
| 190 | | { PUTS("null print_list"); $$ = valtonode(lookup("$record", symtab, 0), CFLD); } |
| 191 | ; |
| 192 | |
| 193 | pe_list: |
| 194 | expr ',' expr {$$ = linkum($1, $3); } |
| 195 | | pe_list ',' expr {$$ = linkum($1, $3); } |
| 196 | | '(' pe_list ')' {$$ = $2; } |
| 197 | ; |
| 198 | |
| 199 | redir: |
| 200 | RELOP |
| 201 | | '|' |
| 202 | ; |
| 203 | |
| 204 | regular_expr: |
| 205 | '/' { startreg(); } |
| 206 | r '/' |
| 207 | { PUTS("/r/"); $$ = $3; } |
| 208 | ; |
| 209 | |
| 210 | r: |
| 211 | CHAR { PUTS("regex CHAR"); $$ = op2(CHAR, (node *) 0, $1); } |
| 212 | | DOT { PUTS("regex DOT"); $$ = op2(DOT, (node *) 0, (node *) 0); } |
| 213 | | CCL { PUTS("regex CCL"); $$ = op2(CCL, (node *) 0, cclenter($1)); } |
| 214 | | NCCL { PUTS("regex NCCL"); $$ = op2(NCCL, (node *) 0, cclenter($1)); } |
| 215 | | '^' { PUTS("regex ^"); $$ = op2(CHAR, (node *) 0, HAT); } |
| 216 | | '$' { PUTS("regex $"); $$ = op2(CHAR, (node *) 0 ,(node *) 0); } |
| 217 | | r OR r { PUTS("regex OR"); $$ = op2(OR, $1, $3); } |
| 218 | | r r %prec CAT |
| 219 | { PUTS("regex CAT"); $$ = op2(CAT, $1, $2); } |
| 220 | | r STAR { PUTS("regex STAR"); $$ = op2(STAR, $1, (node *) 0); } |
| 221 | | r PLUS { PUTS("regex PLUS"); $$ = op2(PLUS, $1, (node *) 0); } |
| 222 | | r QUEST { PUTS("regex QUEST"); $$ = op2(QUEST, $1, (node *) 0); } |
| 223 | | '(' r ')' { PUTS("(regex)"); $$ = $2; } |
| 224 | ; |
| 225 | |
| 226 | rel_expr: |
| 227 | expr RELOP expr |
| 228 | { PUTS("expr relop expr"); $$ = op2($2, $1, $3); } |
| 229 | | '(' rel_expr ')' |
| 230 | { PUTS("(relexpr)"); $$ = $2; } |
| 231 | ; |
| 232 | |
| 233 | st: |
| 234 | NL |
| 235 | | ';' |
| 236 | ; |
| 237 | |
| 238 | simple_stat: |
| 239 | PRINT print_list redir expr |
| 240 | { PUTS("print>stat"); $$ = stat3($1, $2, $3, $4); } |
| 241 | | PRINT print_list |
| 242 | { PUTS("print list"); $$ = stat3($1, $2, nullstat, nullstat); } |
| 243 | | PRINTF print_list redir expr |
| 244 | { PUTS("printf>stat"); $$ = stat3($1, $2, $3, $4); } |
| 245 | | PRINTF print_list |
| 246 | { PUTS("printf list"); $$ = stat3($1, $2, nullstat, nullstat); } |
| 247 | | expr { PUTS("expr"); $$ = exptostat($1); } |
| 248 | | { PUTS("null simple statement"); $$ = (hack)nullstat; } |
| 249 | | error { yyclearin; yyerror("illegal statement"); $$ = (hack)nullstat; } |
| 250 | ; |
| 251 | |
| 252 | statement: |
| 253 | simple_stat st { PUTS("simple stat"); } |
| 254 | | if statement { PUTS("if stat"); $$ = stat3(IF, $1, $2, nullstat); } |
| 255 | | if statement else statement |
| 256 | { PUTS("if-else stat"); $$ = stat3(IF, $1, $2, $4); } |
| 257 | | while statement { PUTS("while stat"); $$ = stat2(WHILE, $1, $2); } |
| 258 | | for { PUTS("for stat"); } |
| 259 | | NEXT st { PUTS("next"); $$ = stat1(NEXT, 0); } |
| 260 | | EXIT st { PUTS("exit"); $$ = stat1(EXIT, 0); } |
| 261 | | EXIT expr st { PUTS("exit"); $$ = stat1(EXIT, $2); } |
| 262 | | BREAK st { PUTS("break"); $$ = stat1(BREAK, 0); } |
| 263 | | CONTINUE st { PUTS("continue"); $$ = stat1(CONTINUE, 0); } |
| 264 | | '{' stat_list '}' { PUTS("{statlist}"); $$ = $2; } |
| 265 | ; |
| 266 | |
| 267 | stat_list: |
| 268 | stat_list statement { PUTS("stat_list stat"); $$ = linkum($1, $2); } |
| 269 | | { PUTS("null stat list"); $$ = (hack)nullstat; } |
| 270 | ; |
| 271 | |
| 272 | while: |
| 273 | WHILE '(' conditional ')' optNL { PUTS("while(cond)"); $$ = $3; } |
| 274 | ; |
| 275 | |
| 276 | for: |
| 277 | FOR '(' simple_stat ';' conditional ';' simple_stat ')' optNL statement |
| 278 | { PUTS("for(e;e;e)"); $$ = stat4(FOR, $3, $5, $7, $10); } |
| 279 | | FOR '(' simple_stat ';' ';' simple_stat ')' optNL statement |
| 280 | { PUTS("for(e;e;e)"); $$ = stat4(FOR, $3, nullstat, $6, $9); } |
| 281 | | FOR '(' VAR IN VAR ')' optNL statement |
| 282 | { PUTS("for(v in v)"); $$ = stat3(IN, $3, $5, $8); } |
| 283 | ; |
| 284 | |
| 285 | %% |