usr/src/lib/libc/tahoe/fpe/cvtud.s

/*
 * Copyright (c) 1986 Regents of the University of California.
 * All rights reserved.
 *
 * This code is derived from software contributed to Berkeley by
 * Computer Consoles Inc.
 *
 * Redistribution and use in source and binary forms are permitted
 * provided that: (1) source distributions retain this entire copyright
 * notice and comment, and (2) distributions including binaries display
 * the following acknowledgement:  ``This product includes software
 * developed by the University of California, Berkeley and its contributors''
 * in the documentation or other materials provided with the distribution
 * and in all advertising materials mentioning features or use of this
 * software. Neither the name of the University nor the names of its
 * contributors may be used to endorse or promote products derived
 * from this software without specific prior written permission.
 * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
 * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
 */

#if defined(SYSLIBC_SCCS) && !defined(lint)
        .asciz "@(#)cvtud.s     1.3 (Berkeley) 6/1/90"
#endif /* SYSLIBC_SCCS and not lint */

#include <tahoemath/fp.h>
#include "DEFS.h"

XENTRY(cvtud, R2|R3|R4|R5)
 #
 #      Some initializations:
 #
        clrl    r2              # r2 - exponent.
        movl    4(fp),r0        # fetch operand.
        jeql    retzero         # return zero.
 #
 #      Compute exponent:
 #
positive:
        ffs     r0,r1
        incl    r1
        addl2   r1,r2
        shrl    r1,r0,r0
        jneq    positive        # look for more set bits.
 #
 # we have the exponent in r2.
 #
        movl    4(fp),r0        # r0,r1 will hold the resulting f.p. number.
        clrl    r1
 #
 #      Shift the fraction part to its proper place:
 #
        subl3   r2,$HID_POS,r3
        jlss    shiftr          # if less then zero we have to shift right.
        shll    r3,r0,r0        # else we shift left.
        jmp     shifted
shiftr:
        mnegl   r3,r3
        shrq    r3,r0,r0
shifted:
        andl2   $CLEARHID,r0    # clear the hidden bit.
        shal    $EXPSHIFT,r2,r2 # shift the exponent to its proper place.
        orl2    $EXPSIGN,r2     # set the exponent sign bit(to bias it).
        orl2    r2,r0           # combine exponent & fraction.
sign_ok:
        ret

retzero:
        clrl    r0
        clrl    r1
        ret