usr/src/lib/libc/vax/string/strcpy.s

/*
 * Copyright (c) 1983 Regents of the University of California.
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms are permitted
 * provided that: (1) source distributions retain this entire copyright
 * notice and comment, and (2) distributions including binaries display
 * the following acknowledgement:  ``This product includes software
 * developed by the University of California, Berkeley and its contributors''
 * in the documentation or other materials provided with the distribution
 * and in all advertising materials mentioning features or use of this
 * software. Neither the name of the University nor the names of its
 * contributors may be used to endorse or promote products derived
 * from this software without specific prior written permission.
 * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
 * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
 */

#if defined(LIBC_SCCS) && !defined(lint)
        .asciz "@(#)strcpy.s    5.6 (Berkeley) 6/1/90"
#endif /* LIBC_SCCS and not lint */

/*
 * Copy string s2 over top of s1.
 * Return base of s1.
 *
 * char *
 * strcpy(s1, s2)
 *      char *s1, *s2;
 */
#include "DEFS.h"

ENTRY(strcpy, R6)
        movl    4(ap), r3       # r3 = s1
        movl    8(ap), r6       # r6 = s2
1:
        locc    $0,$65535,(r6)  # find length of s2
        bneq    2f
        movc3   $65535,(r6),(r3)# copy full block
        movl    r1,r6
        jbr     1b
2:
        subl2   r6,r1           # calculate length
        incl    r1
        movc3   r1,(r6),(r3)    # copy remainder
        movl    4(ap),r0        # return base of s1
        ret