usr/src/lib/libc/vax/sys/Ovfork.s

/*
 * Copyright (c) 1983 Regents of the University of California.
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms are permitted
 * provided that: (1) source distributions retain this entire copyright
 * notice and comment, and (2) distributions including binaries display
 * the following acknowledgement:  ``This product includes software
 * developed by the University of California, Berkeley and its contributors''
 * in the documentation or other materials provided with the distribution
 * and in all advertising materials mentioning features or use of this
 * software. Neither the name of the University nor the names of its
 * contributors may be used to endorse or promote products derived
 * from this software without specific prior written permission.
 * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR
 * IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
 */

#if defined(SYSLIBC_SCCS) && !defined(lint)
        .asciz "@(#)Ovfork.s    5.6 (Berkeley) 6/1/90"
#endif /* SYSLIBC_SCCS and not lint */

/*
 * @(#)vfork.s  4.1 (Berkeley) 12/21/80
 * C library -- vfork
 */

/*
 * pid = vfork();
 *
 * r1 == 0 in parent process, r1 == 1 in child process.
 * r0 == pid of child in parent, r0 == pid of parent in child.
 *
 * trickery here, due to keith sklower, uses ret to clear the stack,
 * and then returns with a jump indirect, since only one person can return
 * with a ret off this stack... we do the ret before we vfork!
 */

        .set    vfork,66
.globl  _vfork

_vfork:
        .word   0x0000
        movl    16(fp),r2
        movab   here,16(fp)
        ret
here:
        chmk    $vfork
        bcc     vforkok
        jmp     verror
vforkok:
        tstl    r1              # child process ?
        bneq    child   # yes
        bcc     parent          # if c-bit not set, fork ok
.globl  _errno
verror:
        movl    r0,_errno
        mnegl   $1,r0
        jmp     (r2)
child:
        clrl    r0
parent:
        jmp     (r2)