BSD 4_1c_2 release

[unix-history] / usr / src / ucb / netser / htable / scan.l

%{
#ifndef lint
static char sccsid[] = "@(#)scan.l      4.1 (Berkeley) 10/20/82";
#endif

#include "y.tab.h"
#include "htable.h"
%}

BLANK   [ \t]
DIGIT   [0-9]
ALPHA   [A-Z]
ANUM    [0-9A-Z]
NAMECHR [0-9A-Z./-]

%%
"NET"           {
                       yylval.number = KW_NET;
                       return (KEYWORD);
               }

"GATEWAY"       {
                       yylval.number = KW_GATEWAY;
                       return (KEYWORD);
               }

"HOST"          {
                       yylval.number = KW_HOST;
                       return (KEYWORD);
               }

{ALPHA}{NAMECHR}*{ANUM} {
                       yylval.namelist = newname(yytext);
                       return (NAME);
               }

{ALPHA}         return (NAME);

{DIGIT}+        {
                       yylval.number = atoi(yytext);
                       return (NUMBER);
               }

"."             return ('.');
":"             return (':');
","             return (',');
"/"             return ('/');
";".*           ;
"\n"{BLANK}+    ;
{BLANK}+        ;
"\n"            return (END);
.               fprintf(stderr, "Illegal char: '%s'\n", yytext);

%%

yywrap()
{
       return (1);
}